0. #lang racket
1.  
2. (require compiler/zo-parse)
3. (define (definition-from-zo zo-file sym mods)
4.   (define the-mod
5.     (let loop ([m (compilation-top-code (with-input-from-file zo-file zo-parse))])
6.       (if (or (equal? (list (mod-name m)) mods)
7.               (equal? (mod-name m) mods))
8.           m
9.           (for/or ([v (in-list (append (mod-pre-submodules m)
10.                                        (mod-post-submodules m)))])
11.             (and (mod? v) (loop v))))))
12.   (and
13.    the-mod
14.    (or
15.     ;; The srcloc in mod-binding-names hashtable is preferable: 1.
16.     ;; Most importantly, it's correct for "definer macros" -- points
17.     ;; to usage of the macro not the macro definition itself. 2. Less
18.     ;; importantly, it points to the identifier instead of the parent
19.     ;; `define`. HOWEVER the hashtable only seems to be present for
20.     ;; the file module -- not for submodules. So as a fallback, try
21.     ;; walking body forms for `lam`s to get the srcloc.
22.     (match (hash-ref (hash-ref (mod-binding-names the-mod) 0 (hash)) sym #f)
23.       [(stx
24.         (struct* stx-obj
25.                  ([srcloc (struct* srcloc
26.                                    ([source source]
27.                                     [line line]
28.                                     [column column]))])))
29.        (list source line (sub1 column))]
30.       [_ #f])
31.     (for/or ([v (in-list (mod-body the-mod))])
32.       (match v
33.         [(def-values
34.            _ids
35.            (inline-variant (closure (? lam? lam) _gen-id)
36.                            _inline))
37.          (match (lam-name lam)
38.            [(vector (== sym) (? path? file) line col _ ...)
39.             (list file line col)]
40.            [_ #f])]
41.         [_ #f])))))

=>