0. #lang racket
1. ; https://gus-massa.blogspot.com.ar/2019/09/more-on-prime-parallelograms.html
2.  
3. (require math/number-theory)
4. (require plot/pict)
5. #;(plot-new-window? #t)
6.  
7. (require plot/utils)
8. (define ((linear-ticks-format/no-sc) min max pre-ticks)
9.   (define digits (digits-for-range min max))
10.   (map (lambda (pt)
11.          (real->plot-label (pre-tick-value pt) digits #f))
12.        pre-ticks))
13. (define (linear-ticks/no-sc) (ticks (linear-ticks-layout) (linear-ticks-format/no-sc)))
14. (plot-x-ticks (linear-ticks/no-sc)) ; almost global change
15. (plot-y-ticks (linear-ticks/no-sc)) ; almost global change
16.  
17. (define (binary-reverse x)
18.   (let loop ([x x] [r 0])
19.     (if (zero? x)
20.        r
21.        (loop (quotient x 2) (+ (* 2 r) (remainder x 2))))))
22.  
23. (define all (for/list ([i (in-range 1 16384)])
24.               (vector i (- i (binary-reverse i)))))
25.  
26. (define prim (for/list ([i (in-range 1 16384)]
27.                         #:when (prime? i))
28.               (vector i (- i (binary-reverse i)))))
29.  
30. (plot #:title "All vs Prime Paralelograms"
31.       (list (points all
32.                     #:sym 'dot
33.                     #:color 'black #:alpha .1)
34.             (points prim
35.                     #:sym 'dot
36.                     #:color 'blue #:alpha .5))
37.       #:x-label "n" #:y-label "f(n)"
38.       #:y-min -8192 #:y-max 16384
39.       #:x-min 0
40.       #:width 400 #:height 600)

=>