0. #lang racket
1.  
2. (require racket/generator)
3.  
4. ; Provide alternatives for sequence constructors.
5. ;
6. ; Define the sequence constructors before the struct
7. ; so that the constructors are available for use in
8. ; `#:property prop:sequence`.
9. (define (in-myvec-stream a-myvec)
10.   (define inner-vec (myvec-v a-myvec))
11.   (for/stream ([index (in-range 0 (vector-length inner-vec))])
12.     (define item (vector-ref inner-vec index))
13.     ; Use `displayln` to verify that the sequence items
14.     ; are created on-demand.
15.     (displayln item)
16.     item))
17.  
18. (define (in-myvec-generator a-myvec)
19.   (define inner-vec (myvec-v a-myvec))
20.   (in-generator
21.     (for ([index (in-range 0 (vector-length inner-vec))])
22.       (define item (vector-ref inner-vec index))
23.       (displayln item)
24.       (yield item))))
25.  
26. ; Pretend that this isn't a normal Racket vector,
27. ; but something else internally, so that we need a
28. ; custom sequence constructor.
29. (struct myvec (v)
30.   #:property prop:sequence
31.   ; Or, alternatively, `in-myvec-gemerator`
32.   in-myvec-stream)
33.  
34. (define (make-myvec . values)
35.   (define a-vec (apply vector values))
36.   (myvec a-vec))
37.  
38. (define (test a-myvec [sequence-constructor #f])
39.   (define the-sequence
40.     (if sequence-constructor
41.         (sequence-constructor a-myvec)
42.         ; Use the value itself as sequence.
43.         a-myvec))
44.   (displayln sequence-constructor)
45.   (for/list ([unused (in-range 0 2)]
46.              [vec-item the-sequence])
47.     vec-item))
48.  
49. (define a-myvec (make-myvec 10 11 12 13))
50.  
51. (test a-myvec in-myvec-stream)
52. (test a-myvec in-myvec-generator)
53. (test a-myvec)

=>

#<procedure:in-myvec-stream> 10 11

'(10 11)

#<procedure:in-myvec-generator> 10 11

'(10 11)

#f 10 11

'(10 11)