0. #lang racket
1. ;; logic bombs 137
2. ;; idk how to get going with this puzzle so I guess it's time to learn racklog https://docs.racket-lang.org/racklog/
3.  
4. (module possible-hits racket
5.   (provide possible-sums possible-hit-set possible-hits)
6.  
7.   (module+ test
8.     (require rackunit)
9.     (define-syntax-rule (test-possible-sums? NAME INPUT EXPECTED)
10.       (test-equal? NAME (possible-sums INPUT) EXPECTED))
11.     (define-syntax-rule (test-possible-hit-set? NAME INPUT EXPECTED)
12.       (test-equal? NAME (possible-hit-set INPUT) EXPECTED)))
13.  
14.   ;; given a list of numbers/options for numbers (as a list) return set of all possible sums of subsets of those numbers
15.   ;; e.g. (possible-sums '(1 2 3)) => (set 0 1 2 3 4 5 6)
16.   ;; when an option is given, use one of but not multiple of the alternatives
17.   ;; e.g. (possible-sums '(1 {10 20})) => (set 0 1 20 21 10 11)
18.   (define (possible-sums single-can-see)
19.     (if (empty? single-can-see)
20.         (set 0)
21.         (let loop ([current (car single-can-see)]
22.                    [rest (cdr single-can-see)]
23.                    [found (set 0)])
24.           (let* ([subsums (possible-sums rest)]
25.                  [newfound (cond [(list? current)
26.                                   (apply set-union
27.                                          (for/list ([current-option current])
28.                                            (list->set (set-map subsums (λ (n) (+ current-option n))))))]
29.                                  [else
30.                                   (list->set (set-map subsums (λ (n) (+ current n))))])]
31.                  [allfound (set-union found newfound)])
32.             (if (empty? rest) allfound
33.                 (loop (car rest) (cdr rest) allfound))))))
34.  
35.   (module+ test
36.     (test-possible-sums? "Can always get 0" '() (set 0))
37.     (test-possible-sums? "Basic with sum" '(1 2) (set 0 1 2 3))
38.     (test-possible-sums? "Alternative can't sum" '({1 2}) (set 0 1 2))
39.     (test-possible-sums? "Multiple alternatives" '({1 2} {10 20}) (set 0 1 2 10 20 11 21 12 22)))
40.  
41.   ;; given a list of what each bomb of the same type can see, return set of
42.   ;; possible target values for that type of bomb (see possible-sums above or test cases for input format)
43.   (define (possible-hit-set can-see)
44.     (if (empty? can-see) (set 0)
45.         (apply set-intersect (map possible-sums can-see))))
46.  
47.   ;; helper producing a list instead of a set
48.   (define possible-hits (compose set->list possible-hit-set))
49.  
50.  
51.   (module+ test
52.     (test-possible-hit-set? "x example"
53.                             '[(1 2 3)
54.                               (3 1 2)]
55.                             (set 0 1 2 3 4 5 6))
56.     (test-possible-hit-set? "y example"
57.                             '[(3 3 3)
58.                               (3 1 {1 2})
59.                               (3 3 3)
60.                               (1 2 2)]
61.                             (set 0 3))
62.     (test-possible-hit-set? "z example"
63.                             '[({1 2} 1 3)
64.                               (1 3 3)
65.                               ({1 2} 1 2)]
66.                             (set 0 1 3 4))
67.     (test-possible-hit-set? "a example"
68.                             '[(3 1 {1 2})]
69.                             (set 0 1 2 3 4 5 6))
70.     (test-possible-hit-set? "b example"
71.                             '[(3 3 1)]
72.                             (set 0 1 3 4 6 7))
73.     (test-possible-hit-set? "c example"
74.                             '[(2 3 1)]
75.                             (set 0 1 2 3 4 5 6))
76.  
77.     (test-possible-hit-set? "can't see anything" '[] (set 0))))
78.  
79. (require racklog)
80. (require 'possible-hits)
81.  
82. ;; how many of a type of bomb are there?
83. (define %bomb-count %empty-rel)
84.  
85. ;; how many targets can each bomb of a type see?
86. (define %can-see %empty-rel)
87.  
88. ;; can a bomb hit given number of targets?
89. (define %can-hit
90.   (%rel (bomb n can-see can-hit)
91.         [(bomb n)
92.          (%can-see bomb can-see)
93.          (%is can-hit (possible-hits can-see))
94.          (%member n can-hit)]))
95.  
96. ;; if a type of bomb hits a number of targets, how many total do all bombs of that type hit?
97. (define %bomb-total
98.   (%rel (bomb hit total-hit count)
99.         [(bomb hit total-hit)
100.          (%bomb-count bomb count)
101.          (%is total-hit (* hit count))]))
102.  
103. ;; %true if list has no repeated elements
104. (define %distinct
105.   (%rel (l h t)
106.         [('()) %true]
107.         [((cons h t))
108.          (%not (%member h t))
109.          (%distinct t)]))
110.  
111. ;; for a list of bombs and a list of how many targets that type of bomb hits, how many total targets are hit?
112. (define %combined-total
113.   (%rel (bombs hits total totals)
114.         [(bombs hits total)
115.          (%andmap %bomb-total bombs hits totals)
116.          (%is total (apply + totals))]))
117.  
118. ;; number of targets, list of bombs, list of hits each bomb does
119. (define %hits
120.   (%rel (target-count bombs hits totals)
121.         [(target-count bombs hits)
122.          (%andmap %can-hit bombs hits)
123.          (%distinct hits)
124.          (%combined-total bombs hits target-count)]))
125.  
126. ;;;;;;;;;;;;;;;; solve it ;;;;;;;;;;;;;;;;
127.  
128. (%assert! %bomb-count ()
129.           [('x 2)]
130.           [('y 4)]
131.           [('z 3)]
132.           [('a 1)]
133.           [('b 1)]
134.           [('c 1)])
135. (%assert! %can-see ()
136.           [('x '[(3 1 2)
137.                  (3 1 2)])]
138.           [('y '[(3 3 3)
139.                  (3 1 {1 2})
140.                  (3 3 3)
141.                  (1 2 2)])]
142.           [('z '[({1 2} 1 3)
143.                  (1 3 3)
144.                  ({1 2} 1 2)])]
145.           [('a '[(3 1 {1 2})])]
146.           [('b '[(3 3 1)])]
147.           [('c '[(2 1 3)])])
148.  
149. (displayln "All possible combinations from start of puzzle:")
150. (%find-all (x y z a b c)
151.            (%hits 34 '(x y z a b c) (list x y z a b c)))
152. (displayln "")
153. (displayln "Remove impossible options for %can-see:")
154. (define-syntax-rule (%clear-rel! REL)
155.   (set! REL %empty-rel))
156. (%clear-rel! %can-see)
157. (%assert! %can-see ()
158.           [('x '[(3 2)
159.                  (3 1 2)])]
160.           [('y '[(3 3 3)
161.                  (3 1 {1 2})
162.                  (3 3 3)
163.                  (1 2 2)])]
164.           [('z '[({1 2} 1 3)
165.                  (1 3)
166.                  ({1 2} 2)])]
167.           [('a '[(3 1 {1 2})])]
168.           [('b '[(3 3 1)])]
169.           [('c '[(2 1 3)])])
170. (%find-all (x y z a b c)
171.            (%hits 34 '(x y z a b c) (list x y z a b c)))
172. (displayln "")
173. (displayln "Constrain hit counts where possible:")
174. (%find-all (x y z a b c)
175.            (%and (%hits 34
176.                         '(x y z a b c)
177.                         (list x y z a b c))
178.                  (%>= x 2)
179.                  (%>= y 3)
180.                  (%>= z 1)
181.                  (%>= a 2)
182.                  (%>= c 2)))

=>

All possible combinations from start of puzzle:

'(((x . 6) (y . 3) (z . 1) (a . 5) (b . 0) (c . 2))   ((x . 6) (y . 3) (z . 1) (a . 2) (b . 0) (c . 5))   ((x . 6) (y . 3) (z . 0) (a . 5) (b . 4) (c . 1))   ((x . 6) (y . 3) (z . 0) (a . 5) (b . 1) (c . 4))   ((x . 6) (y . 3) (z . 0) (a . 4) (b . 1) (c . 5))   ((x . 6) (y . 3) (z . 0) (a . 2) (b . 7) (c . 1))   ((x . 6) (y . 3) (z . 0) (a . 1) (b . 7) (c . 2))   ((x . 6) (y . 3) (z . 0) (a . 1) (b . 4) (c . 5))   ((x . 6) (y . 0) (z . 4) (a . 5) (b . 3) (c . 2))   ((x . 6) (y . 0) (z . 4) (a . 2) (b . 7) (c . 1))   ((x . 6) (y . 0) (z . 4) (a . 2) (b . 3) (c . 5))   ((x . 6) (y . 0) (z . 4) (a . 1) (b . 7) (c . 2))   ((x . 6) (y . 0) (z . 3) (a . 5) (b . 7) (c . 1))   ((x . 6) (y . 0) (z . 3) (a . 4) (b . 7) (c . 2))   ((x . 6) (y . 0) (z . 3) (a . 2) (b . 7) (c . 4))   ((x . 6) (y . 0) (z . 3) (a . 1) (b . 7) (c . 5))   ((x . 5) (y . 3) (z . 1) (a . 2) (b . 7) (c . 0))   ((x . 5) (y . 3) (z . 1) (a . 0) (b . 7) (c . 2))   ((x . 5) (y . 3) (z . 0) (a . 6) (b . 4) (c . 2))   ((x . 5) (y . 3) (z . 0) (a . 4) (b . 7) (c . 1))   ((x . 5) (y . 3) (z . 0) (a . 4) (b . 6) (c . 2))   ((x . 5) (y . 3) (z . 0) (a . 2) (b . 6) (c . 4))   ((x . 5) (y . 3) (z . 0) (a . 2) (b . 4) (c . 6))   ((x . 5) (y . 3) (z . 0) (a . 1) (b . 7) (c . 4))   ((x . 5) (y . 0) (z . 4) (a . 3) (b . 7) (c . 2))   ((x . 5) (y . 0) (z . 4) (a . 2) (b . 7) (c . 3))   ((x . 5) (y . 0) (z . 3) (a . 6) (b . 7) (c . 2))   ((x . 5) (y . 0) (z . 3) (a . 2) (b . 7) (c . 6))   ((x . 4) (y . 3) (z . 1) (a . 6) (b . 0) (c . 5))   ((x . 4) (y . 3) (z . 1) (a . 5) (b . 6) (c . 0))   ((x . 4) (y . 3) (z . 1) (a . 5) (b . 0) (c . 6))   ((x . 4) (y . 3) (z . 1) (a . 0) (b . 6) (c . 5))   ((x . 4) (y . 3) (z . 0) (a . 6) (b . 7) (c . 1))   ((x . 4) (y . 3) (z . 0) (a . 5) (b . 7) (c . 2))   ((x . 4) (y . 3) (z . 0) (a . 2) (b . 7) (c . 5))   ((x . 4) (y . 3) (z . 0) (a . 1) (b . 7) (c . 6))   ((x . 2) (y . 3) (z . 4) (a . 5) (b . 1) (c . 0))   ((x . 2) (y . 3) (z . 4) (a . 5) (b . 0) (c . 1))   ((x . 2) (y . 3) (z . 4) (a . 1) (b . 0) (c . 5))   ((x . 2) (y . 3) (z . 4) (a . 0) (b . 1) (c . 5))   ((x . 2) (y . 3) (z . 1) (a . 6) (b . 4) (c . 5))   ((x . 2) (y . 3) (z . 1) (a . 5) (b . 6) (c . 4))   ((x . 2) (y . 3) (z . 1) (a . 5) (b . 4) (c . 6))   ((x . 2) (y . 3) (z . 1) (a . 4) (b . 6) (c . 5))   ((x . 2) (y . 3) (z . 0) (a . 6) (b . 7) (c . 5))   ((x . 2) (y . 3) (z . 0) (a . 5) (b . 7) (c . 6))   ((x . 2) (y . 0) (z . 4) (a . 6) (b . 7) (c . 5))   ((x . 2) (y . 0) (z . 4) (a . 5) (b . 7) (c . 6))   ((x . 1) (y . 3) (z . 4) (a . 6) (b . 0) (c . 2))   ((x . 1) (y . 3) (z . 4) (a . 2) (b . 6) (c . 0))   ((x . 1) (y . 3) (z . 4) (a . 2) (b . 0) (c . 6))   ((x . 1) (y . 3) (z . 4) (a . 0) (b . 6) (c . 2))   ((x . 0) (y . 3) (z . 4) (a . 2) (b . 7) (c . 1))   ((x . 0) (y . 3) (z . 4) (a . 1) (b . 7) (c . 2)))

Remove impossible options for %can-see:

'(((x . 5) (y . 3) (z . 1) (a . 2) (b . 7) (c . 0))   ((x . 5) (y . 3) (z . 1) (a . 0) (b . 7) (c . 2))   ((x . 5) (y . 3) (z . 0) (a . 6) (b . 4) (c . 2))   ((x . 5) (y . 3) (z . 0) (a . 4) (b . 7) (c . 1))   ((x . 5) (y . 3) (z . 0) (a . 4) (b . 6) (c . 2))   ((x . 5) (y . 3) (z . 0) (a . 2) (b . 6) (c . 4))   ((x . 5) (y . 3) (z . 0) (a . 2) (b . 4) (c . 6))   ((x . 5) (y . 3) (z . 0) (a . 1) (b . 7) (c . 4))   ((x . 5) (y . 0) (z . 4) (a . 3) (b . 7) (c . 2))   ((x . 5) (y . 0) (z . 4) (a . 2) (b . 7) (c . 3))   ((x . 5) (y . 0) (z . 3) (a . 6) (b . 7) (c . 2))   ((x . 5) (y . 0) (z . 3) (a . 2) (b . 7) (c . 6))   ((x . 2) (y . 3) (z . 4) (a . 5) (b . 1) (c . 0))   ((x . 2) (y . 3) (z . 4) (a . 5) (b . 0) (c . 1))   ((x . 2) (y . 3) (z . 4) (a . 1) (b . 0) (c . 5))   ((x . 2) (y . 3) (z . 4) (a . 0) (b . 1) (c . 5))   ((x . 2) (y . 3) (z . 1) (a . 6) (b . 4) (c . 5))   ((x . 2) (y . 3) (z . 1) (a . 5) (b . 6) (c . 4))   ((x . 2) (y . 3) (z . 1) (a . 5) (b . 4) (c . 6))   ((x . 2) (y . 3) (z . 1) (a . 4) (b . 6) (c . 5))   ((x . 2) (y . 3) (z . 0) (a . 6) (b . 7) (c . 5))   ((x . 2) (y . 3) (z . 0) (a . 5) (b . 7) (c . 6))   ((x . 2) (y . 0) (z . 4) (a . 6) (b . 7) (c . 5))   ((x . 2) (y . 0) (z . 4) (a . 5) (b . 7) (c . 6))   ((x . 0) (y . 3) (z . 4) (a . 2) (b . 7) (c . 1))   ((x . 0) (y . 3) (z . 4) (a . 1) (b . 7) (c . 2)))

Constrain hit counts where possible:

'(((x . 2) (y . 3) (z . 1) (a . 6) (b . 4) (c . 5))   ((x . 2) (y . 3) (z . 1) (a . 5) (b . 6) (c . 4))   ((x . 2) (y . 3) (z . 1) (a . 5) (b . 4) (c . 6))   ((x . 2) (y . 3) (z . 1) (a . 4) (b . 6) (c . 5)))