0. #lang racket/base
1.  
2. (require (for-syntax racket/base
3.                      syntax/parse))
4.  
5. (define-syntax (demo stx)
6.   (syntax-parse stx
7.     [(_ the-one:expr the-other:expr)
8.      #'(begin
9.          (define (the-first) the-one)
10.          (define (the-second) the-other))]))
11.  
12. (demo 1 2)
13.  
14.  
15. (define-syntax (demo-unhygienic stx)
16.   (syntax-parse stx
17.     ((_ the-one:expr the-other:expr)
18.      (with-syntax
19.        ((the-first (datum->syntax stx 'the-first))
20.         (the-second (datum->syntax stx 'the-second)))
21.        #'(begin
22.            (define (the-first) the-one)
23.            (define (the-second) the-other))))))
24.  
25. (demo-unhygienic 3 4)
26. (displayln (the-first))
27. (displayln (the-second))
28.  
29.  
30. (define-syntax (demo-hygienic stx)
31.   (syntax-parse stx
32.     [(_ the-first-name:id the-second-name:id the-one:expr the-other:expr)
33.      #'(begin
34.          (define (the-first-name) the-one)
35.          (define (the-second-name) the-other))]))
36.  
37. (demo-hygienic the-first-one the-second-one 5 6)
38.  
39. (displayln (the-first-one))
40. (displayln (the-second-one))

=>

3

4

5

6