0. #lang racket
1.  
2. ;; A solver for the following puzzle:
3. ;; Given 5 integers a, b, c, d, and e,
4. ;; find an expression that combines a, b, c, and d with arithmetic operations (+, -, *, and /) to get e.
5.  
6. (require srfi/1)
7. (require racket/generator)
8.  
9. (define ops '(+ - * /))
10.  
11. (define (splits l)
12.   (for/list ([i (in-range 1 (length l))])
13.     (cons (take l i) (drop l i))))
14.  
15. ;; produces a sequence (usually lazy) of all possible combinations of `nums'
16. ;; using operators in `ops'.
17. (define (combine nums)
18.   (match nums
19.     ['() (error "impossible")]
20.     [(list x) (list x)]
21.     [_ (in-generator
22.         (for* ([halves (splits nums)]
23.                [left   (combine (car halves))]
24.                [right  (combine (cdr halves))]
25.                [op     ops])
26.           (yield `(,op ,left ,right))))]))
27.  
28. (define (eval-expr e)
29.   (with-handlers ([exn:fail:contract:divide-by-zero?
30.                    (lambda (exn) +inf.0)])
31.     (eval e)))
32.  
33. (define (solve n1 n2 n3 n4 target)
34.   (delete-duplicates
35.    (for*/list ([p (permutations (list n1 n2 n3 n4))]
36.                [l (combine p)]
37.                #:when (= target (eval-expr l)))
38.      l)))
39.  
40. ;; Example: combine 6, 6, 5, and 2 with arithmetic operations to get 17:
41. ;; > (solve 6 6 5 2 17)
42. ;; '((* 6 (+ (/ 5 6) 2))
43. ;;   (* (+ (/ 5 6) 2) 6)
44. ;;   (* 6 (+ 2 (/ 5 6)))
45. ;;   (* (+ 2 (/ 5 6)) 6))
46.  
47. ;; 5 / 6 = 5/6
48. ;;   + 2 = 17/6
49. ;;   * 6 = 17
50.  
51. (pretty-print (solve 6 6 5 2 17))

=>

'((* 6 (+ (/ 5 6) 2))   (* (+ (/ 5 6) 2) 6)   (* 6 (+ 2 (/ 5 6)))   (* (+ 2 (/ 5 6)) 6))