0. #lang racket/base
1.  
2. ;; Example of using a pipe to create a modified input-port.
3. ;; This example simply skips 255 bytes.
4. (define (make-skipping-255-port in)
5.   ;; Create a pipe, which has in and out ports.
6.   (define-values (pin pout) (make-pipe))
7.   ;; Racket has threads! Start one that reads from the original input,
8.   ;; and writes to the pipe's output. It's important to close the
9.   ;; output when done.
10.   (thread (λ ()
11.             ;; You could write this many ways, but the `in-port`
12.             ;; sequence is handy here, as is using an #:unless clause
13.             ;; with `for`.
14.             (for ([b (in-port read-byte in)]
15.                   #:unless (equal? b 255))
16.               (write-byte b pout))
17.             (close-output-port pout)))
18.   ;; Return the input end of the pipe.
19.   pin)
20.  
21. ;; Trying it out
22. (define original-in (open-input-bytes (bytes 1 2 3 255 1 2 3)))
23. (define skipping-in (make-skipping-255-port original-in))
24. (for/list ([b (in-port read-byte skipping-in)])
25.   b)

=>

'(1 2 3 1 2 3)