0. #lang racket/base
1.  
2. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
3. ;; require
4.  
5. (require math/statistics
6.          plot/pict
7.          plot/utils
8.          racket/dict
9.          racket/function
10.          racket/list)
11.  
12. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
13. ;; violin
14.  
15. (define (violin vals
16.                 #:bandwidth [bandwidth (silverman (second vals))]
17.                 #:x-min [x-min #f]
18.                 #:x-max [x-max #f]
19.                 #:y-min [y-min #f]
20.                 #:y-max [y-max #f]
21.                 #:color [color (interval-color)]
22.                 #:style [style (interval-style)]
23.                 #:line1-color [line1-color (interval-line1-color)]
24.                 #:line1-width [line1-width (interval-line1-width)]
25.                 #:line1-style [line1-style (interval-line1-style)]
26.                 #:line2-color [line2-color (interval-line2-color)]
27.                 #:line2-width [line2-width (interval-line2-width)]
28.                 #:line2-style [line2-style (interval-line2-style)]
29.                 #:alpha [alpha (interval-alpha)]
30.                 #:label [label #f])
31.   (define y-shift (first vals))
32.   (define-values (f low high)
33.     (kde (second vals) bandwidth))
34.   (define x-axis (const 0))
35.   (define x-min* (or x-min low))
36.   (define x-max* (or x-max high))
37.   (define settings
38.     `([#:y-min . ,y-min]
39.       [#:y-max . ,y-max]
40.       [#:color . ,color]
41.       [#:style . ,style]
42.       [#:line1-color . ,line1-color]
43.       [#:line1-width . ,line1-width]
44.       [#:line1-style . ,line1-style]
45.       [#:line2-color . ,line2-color]
46.       [#:line2-width . ,line2-width]
47.       [#:line2-style . ,line2-style]
48.       [#:alpha . ,alpha]
49.       [#:label . ,label]))
50.   (list (keyword-apply/dict function-interval settings
51.                             (shift-up (invert f) y-shift)
52.                             (shift-up f y-shift)
53.                             x-min* x-max* null)))
54.  
55. (define (shift-up f shift)
56.   (λ (x)
57.     (+ (f x) shift)))
58.  
59. (define ((invert f) x)
60.   (- (f x)))
61.  
62. (define (silverman vals)
63.   (define iqr (interquartile-range vals))
64.   (define n (length vals))
65.   (* 0.9
66.      (min (stddev vals) (/ iqr 1.34))
67.      (expt n -0.2)))
68.  
69. (define (interquartile-range vals)
70.   (- (quantile 3/4 < vals)
71.      (quantile 1/4 < vals)))
72.  
73. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
74. ;; example
75. ;;
76. ;; `(violin (list y-center x-data))`
77. ;;
78.  
79. (parameterize ([plot-y-ticks no-ticks]
80.                [plot-y-label #f]
81.                [plot-x-far-ticks no-ticks]
82.                [plot-x-label "Time (sec)"])
83.   (plot (list (violin `[0.00 (0 1 1 2 3 4 4 4 5 6 7 9 10 10 10 11 13)])
84.               (violin `[0.30 (15 16 17 18 19 20 20 21 23 30)]))))

=>