0. #lang racket
1. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2. ;; require
3.  
4. (require math/statistics
5.          plot/pict
6.          plot/utils)
7.  
8. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
9. ;; functions
10.  
11. (define (violin vals
12.                 #:bandwidth [bandwidth (silverman (second vals))]
13.                 #:x-min [x-min #f]
14.                 #:x-max [x-max #f]
15.                 #:y-min [y-min #f]
16.                 #:y-max [y-max #f]
17.                 #:color [color (interval-color)]
18.                 #:style [style (interval-style)]
19.                 #:line1-color [line1-color (interval-line1-color)]
20.                 #:line1-width [line1-width (interval-line1-width)]
21.                 #:line1-style [line1-style (interval-line1-style)]
22.                 #:line2-color [line2-color (interval-line2-color)]
23.                 #:line2-width [line2-width (interval-line2-width)]
24.                 #:line2-style [line2-style (interval-line2-style)]
25.                 #:alpha [alpha (interval-alpha)]
26.                 #:label [label #f])
27.   (define y-shift (first vals))
28.   (define-values (f low high)
29.     (kde (second vals) bandwidth))
30.   (define x-axis (const 0))
31.   (define x-min* (or x-min low))
32.   (define x-max* (or x-max high))
33.   (define settings
34.     `([#:y-min . ,y-min]
35.       [#:y-max . ,y-max]
36.       [#:color . ,color]
37.       [#:style . ,style]
38.       [#:line1-color . ,line1-color]
39.       [#:line1-width . ,line1-width]
40.       [#:line1-style . ,line1-style]
41.       [#:line2-color . ,line2-color]
42.       [#:line2-width . ,line2-width]
43.       [#:line2-style . ,line2-style]
44.       [#:alpha . ,alpha]
45.       [#:label . ,label]))
46.   (list (keyword-apply/dict function-interval settings
47.                             (shift-up (invert f) y-shift)
48.                             (shift-up f y-shift)
49.                             x-min* x-max* null)))
50.  
51. (define (shift-up f shift)
52.   (λ (x)
53.     (+ (f x) shift)))
54.  
55. (define ((invert f) x)
56.   (- (f x)))
57.  
58. (define (silverman vals)
59.   (define iqr (interquartile-range vals))
60.   (define n (length vals))
61.   (* 0.9
62.      (min (stddev vals) (/ iqr 1.34))
63.      (expt n -0.2)))
64.  
65. (define (interquartile-range vals)
66.   (- (quantile 3/4 < vals)
67.      (quantile 1/4 < vals)))
68.  
69. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
70. ;; example
71. ;;
72. ;; `(violin (list y-center x-data))`
73. ;;
74.  
75. (parameterize ([plot-y-ticks no-ticks]
76.                [plot-y-label #f]
77.                [plot-x-far-ticks no-ticks]
78.                [plot-x-label "Time (sec)"])
79.   (plot (list (violin `[0.00 (0 1 1 2 3 4 4 4 5 6 7 9 10 10 10 11 13)])
80.               (violin `[0.30 (15 16 17 18 19 20 20 21 23 30)]))))

=>